mirror of
https://github.com/chenasraf/nvim-treesitter.git
synced 2026-05-18 01:39:00 +00:00
9a51f860c1
Git config's sections, variable names, and (sometimes) subsections are case-insensitive. This commit proposes to match the full lowercase variants in addition to the non-normalised, lowerCamelCase ones. See `git help config`
60 lines
970 B
Scheme
60 lines
970 B
Scheme
; Sections
|
|
(section_name) @markup.heading
|
|
|
|
((section_name) @keyword.import
|
|
(#eq? @keyword.import "include"))
|
|
|
|
((section_header
|
|
(section_name) @keyword.import
|
|
(subsection_name))
|
|
(#any-of? @keyword.import "includeIf" "includeif"))
|
|
|
|
(variable
|
|
(name) @property)
|
|
|
|
; Operators
|
|
"=" @operator
|
|
|
|
; Literals
|
|
(integer) @number
|
|
|
|
[
|
|
(true)
|
|
(false)
|
|
] @boolean
|
|
|
|
(string) @string
|
|
|
|
(escape_sequence) @string.escape
|
|
|
|
((string) @string.special.path
|
|
(#lua-match? @string.special.path "^[.]?[.]?[/]"))
|
|
|
|
((string) @string.special.path
|
|
(#lua-match? @string.special.path "^[~]"))
|
|
|
|
(section_header
|
|
[
|
|
"\""
|
|
(subsection_name)
|
|
] @string.special)
|
|
|
|
((section_header
|
|
(section_name) @_name
|
|
(subsection_name) @string.special.url)
|
|
(#any-of? @_name "credential" "url"))
|
|
|
|
((variable
|
|
(name) @_name
|
|
value: (string) @string.special.url)
|
|
(#any-of? @_name "insteadOf" "insteadof"))
|
|
|
|
; Punctuation
|
|
[
|
|
"["
|
|
"]"
|
|
] @punctuation.bracket
|
|
|
|
; Comments
|
|
(comment) @comment @spell
|