From 3625e099b09bff2db5f04082cb09ba679525980c Mon Sep 17 00:00:00 2001
From: Vadim Kazakov <yads12@gmail.com>
Date: Thu, 1 Jun 2023 18:19:02 -0600
Subject: [PATCH] Add glimmer support in TS (#294)

---
 after/queries/glimmer/matchup.scm | 34 +++++++++++++++++++++++++++++++
 1 file changed, 34 insertions(+)
 create mode 100644 after/queries/glimmer/matchup.scm

diff --git a/after/queries/glimmer/matchup.scm b/after/queries/glimmer/matchup.scm
new file mode 100644
index 0000000..bf55ff3
--- /dev/null
+++ b/after/queries/glimmer/matchup.scm
@@ -0,0 +1,34 @@
+; inherits: quote
+
+(element_node) @scope.tag
+
+(element_node_start (tag_name) @open.tag)
+(element_node_end
+  (tag_name) @close.tag
+  (#offset! @close.tag 0 -1 0 0))
+
+(block_statement
+  (block_statement_start) @open.block
+  (block_statement_end) @close.block
+  ) @scope.block
+; {{else if ...}}
+(mustache_statement
+  (helper_invocation helper: (identifier) @mid.block.1 (#lua-match? @mid.block.1 "else"))
+  )
+; {{else}}
+(mustache_statement ((identifier) @mid.block.2 (#lua-match? @mid.block.2 "else")))
+
+(element_node_void
+  (tag_name) @open.selftag
+  "/>" @close.selftag
+  ) @scope.selftag
+
+(mustache_statement
+  [(helper_invocation) "{{"] @open.mustache
+  "}}" @close.mustache
+  ) @scope.mustache
+
+(sub_expression
+  [(helper_invocation) "("] @open.subexpr
+  ")" @close.subexpr
+  ) @scope.subexpr