From dc0400017babfcf5eae27db5003590a1e44518c3 Mon Sep 17 00:00:00 2001
From: "Andy K. Massimino" <f8a663@normed.space>
Date: Sun, 25 Apr 2021 11:45:29 -0400
Subject: [PATCH] Add TS C++ queries

---
 after/queries/cpp/matchup.scm | 26 ++++++++++++++++++++++++++
 1 file changed, 26 insertions(+)
 create mode 100644 after/queries/cpp/matchup.scm

diff --git a/after/queries/cpp/matchup.scm b/after/queries/cpp/matchup.scm
new file mode 100644
index 0000000..e8f9264
--- /dev/null
+++ b/after/queries/cpp/matchup.scm
@@ -0,0 +1,26 @@
+(preproc_ifdef
+  ["#ifdef" "#ifndef"] @open.def
+  "#endif" @close.def) @scope.def
+
+(preproc_if
+  "#if" @open.def
+  "#endif" @close.def) @scope.def
+
+(preproc_elif "#elif" @mid.def.1)
+(preproc_else "#else" @mid.def.2)
+
+(switch_statement
+  "switch" @open.switch
+  body: (compound_statement
+    (case_statement "case" @mid.switch.1)?
+    (case_statement "default" @mid.switch.2)?)) @scope.switch
+
+; 'else' and 'else if'
+(if_statement
+  "else" @_start (if_statement "if" @_end)?
+  (#make-range! "mid.if.1" @_start @_end))
+
+; if
+(compound_statement
+  (if_statement
+    "if" @open.if) @scope.if)