feat: add kos parser and queries (#8389)

SUPPORTED_LANGUAGES.md

@@ -157,6 +157,7 @@ jsx (queries only)[^jsx] | unstable | `HFIJ ` | @steelsojka
 [kconfig](https://github.com/tree-sitter-grammars/tree-sitter-kconfig) | unstable | `HFIJL` | @amaanq
 [kdl](https://github.com/tree-sitter-grammars/tree-sitter-kdl) | unstable | `HFIJL` | @amaanq
 [kitty](https://github.com/OXY2DEV/tree-sitter-kitty) | unstable | `H  J ` | @OXY2DEV
+[kos](https://github.com/kos-lang/tree-sitter-kos) | unstable | `HF JL` | @cdragan
 [kotlin](https://github.com/fwcd/tree-sitter-kotlin) | unstable | `HF JL` | @SalBakraa
 [koto](https://github.com/koto-lang/tree-sitter-koto) | unstable | `HF JL` | @irh
 [kusto](https://github.com/Willem-J-an/tree-sitter-kusto) | unstable | `H  J ` | @Willem-J-an

lua/nvim-treesitter/parsers.lua

@@ -1187,6 +1187,14 @@ return {
     maintainers = { '@OXY2DEV' },
     tier = 2,
   },
+  kos = {
+    install_info = {
+      revision = '5f11d41b3150b0837e8b3964151ebb7fc4f367e9',
+      url = 'https://github.com/kos-lang/tree-sitter-kos',
+    },
+    maintainers = { '@cdragan' },
+    tier = 2,
+  },
   kotlin = {
     install_info = {
       revision = '57fb4560ba8641865bc0baa6b3f413b236112c4c',

runtime/queries/kos/folds.scm

@@ -0,0 +1,19 @@
+[
+  (function_decl)
+  (constructor_literal)
+  (function_literal)
+  (class_decl)
+  (class_literal)
+  (do_statement)
+  (if_statement)
+  (try_statement)
+  (defer_statement)
+  (with_statement)
+  (switch_statement)
+  (switch_case)
+  (default_case)
+  (loop_statement)
+  (repeat_statement)
+  (while_statement)
+  (for_statement)
+] @fold

runtime/queries/kos/highlights.scm

@@ -0,0 +1,141 @@
+(hash_bang) @keyword.directive
+
+(comment) @comment @spell
+
+(number) @number
+
+(identifier) @variable
+
+(property_identifier) @property
+
+[
+  (string_literal)
+  (string_literal_begin)
+  (string_literal_continuation)
+  (string_literal_end)
+] @string
+
+[
+  "case"
+  "default"
+  "else"
+  "if"
+  "switch"
+] @keyword.conditional
+
+"import" @keyword.import
+
+[
+  (break_statement)
+  (continue_statement)
+  "for"
+  "loop"
+  "repeat"
+  "while"
+] @keyword.repeat
+
+(for_statement
+  "in" @keyword.repeat)
+
+"class" @keyword.type
+
+[
+  "return"
+  "yield"
+] @keyword.return
+
+[
+  "catch"
+  "defer"
+  "throw"
+  "try"
+] @keyword.exception
+
+[
+  "constructor"
+  "fun"
+  "=>"
+] @keyword.function
+
+[
+  "_"
+  (line)
+  "assert"
+  ;"async"
+  "const"
+  "do"
+  "extends"
+  (fallthrough_statement)
+  ;"get"
+  ;"match"
+  "public"
+  ;"set"
+  ;"static"
+  "var"
+  "with"
+] @keyword
+
+[
+  (this)
+  (super)
+] @variable.builtin
+
+[
+  (false)
+  (true)
+] @boolean
+
+(void) @constant.builtin
+
+[
+  "("
+  ")"
+  "["
+  "]"
+  "{"
+  "}"
+] @punctuation.bracket
+
+[
+  ";"
+  ":"
+  "."
+  ","
+] @punctuation.delimiter
+
+[
+  (arithmetic_assignment_operator)
+  (comparison_operator)
+  (bitwise_operator)
+  (additive_operator)
+  (multiplicative_operator)
+  (logical_operator)
+  (unary_operator)
+  "->"
+  "..."
+  "="
+  "?"
+] @operator
+
+(conditional_expression
+  [
+    "?"
+    ":"
+  ] @keyword.conditional.ternary)
+
+(class_member
+  (function_decl
+    name: (identifier) @function.method))
+
+(function_decl
+  name: (identifier) @function)
+
+(class_decl
+  name: (identifier) @type)
+
+(invocation
+  (identifier) @function.call)
+
+(invocation
+  (refinement
+    property: (property_identifier) @function.method.call))

runtime/queries/kos/injections.scm

@@ -0,0 +1,6 @@
+(((comment) @_jsdoc_comment
+  (#lua-match? @_jsdoc_comment "^/[*][*][^*].*[*]/$")) @injection.content
+  (#set! injection.language "jsdoc"))
+
+((comment) @injection.content
+  (#set! injection.language "comment"))

runtime/queries/kos/locals.scm

@@ -0,0 +1,41 @@
+; Scopes
+;-------
+(compound_statement) @local.scope
+
+(for_statement) @local.scope
+
+(function_decl) @local.scope
+
+(constructor_literal) @local.scope
+
+(function_literal) @local.scope
+
+(with_statement) @local.scope
+
+(catch_clause) @local.scope
+
+; Definitions
+;------------
+(variable_decl
+  variable: (identifier) @local.definition.var)
+
+(parameter
+  parameter: (identifier) @local.definition.parameter)
+
+(import
+  module: (identifier) @local.definition.import)
+
+(import
+  symbol: (identifier) @local.definition.import)
+
+(function_decl
+  name: (identifier) @local.definition.function
+  (#set! definition.var.scope parent))
+
+(class_decl
+  name: (identifier) @local.definition.type
+  (#set! definition.var.scope parent))
+
+; References
+;------------
+(identifier) @local.reference

tests/query/highlights/kos/test.kos

@@ -0,0 +1,149 @@
+#!/usr/bin/env kos
+# ^ keyword.directive
+public var item = 1;
+# ^ keyword
+#      ^ keyword
+#          ^ variable
+#               ^ operator
+#                 ^ number
+#                  ^ punctuation.delimiter
+
+# hash comment
+# <- @comment @spell
+
+// slash comment
+# <- @comment @spell
+
+/* block comment */
+# <- @comment @spell
+
+fun name(arg1,
+# ^ keyword.function
+#   ^ function
+#       ^ punctuation.bracket
+#        ^ variable
+#            ^ punctuation.delimiter
+         arg2 = "default",
+#        ^ variable
+#             ^ operator
+#               ^ string
+#                        ^ punctuation.delimiter
+         arg3...)
+#        ^ variable
+#            ^ operator
+#               ^ punctuation.bracket
+{
+# <- punctuation.bracket
+    arg1 += 1
+    # ^ variable
+    #    ^ operator
+    #       ^ number
+    arg1 -= 2
+    # ^ variable
+    #    ^ operator
+    #       ^ number
+    arg1 *= 3
+    # ^ variable
+    #    ^ operator
+    #       ^ number
+    arg1 /= 4
+    # ^ variable
+    #    ^ operator
+    #       ^ number
+    arg1 %= 5
+    # ^ variable
+    #    ^ operator
+    #       ^ number
+    arg1 |= 6
+    # ^ variable
+    #    ^ operator
+    #       ^ number
+    arg1 &= 7
+    # ^ variable
+    #    ^ operator
+    #       ^ number
+    arg1 ^= 8
+    # ^ variable
+    #    ^ operator
+    #       ^ number
+    arg1 <<= 9
+    # ^ variable
+    #    ^ operator
+    #        ^ number
+    arg1 >>= 10
+    # ^ variable
+    #    ^ operator
+    #        ^ number
+    arg1 >>>= 11
+    # ^ variable
+    #    ^ operator
+    #         ^ number
+    arg1.prop[arg1](arg1)[void] = true
+    # ^ variable
+    #   ^ punctuation.delimiter
+    #    ^ property
+    #        ^ punctuation.bracket
+    #         ^ variable
+    #             ^ punctuation.bracket
+    #              ^ punctuation.bracket
+    #               ^ variable
+    #                   ^ punctuation.bracket
+    #                    ^ punctuation.bracket
+    #                     ^ constant.builtin
+    #                           ^ operator
+    #                             ^ boolean
+    arg1 = 1 * (arg1 + 2) / arg1 - 3 % arg1
+    # ^ variable
+    #    ^ operator
+    #      ^ number
+    #        ^ operator
+    #          ^ punctuation.bracket
+    #           ^ variable
+    #                ^ operator
+    #                  ^ number
+    #                   ^ punctuation.bracket
+    #                     ^ operator
+    #                       ^ variable
+    #                            ^ operator
+    #                              ^ number
+    #                                ^ operator
+    #                                  ^ variable
+    for const elem in arg1 {
+    # ^ keyword.repeat
+    #   ^ keyword
+    #         ^ variable
+    #              ^ keyword.repeat
+    #                 ^ variable
+    #                      ^ punctuation.bracket
+        if elem {
+    #   ^ keyword.conditional
+    #      ^ variable
+    #           ^ punctuation.bracket
+            continue
+    #       ^ keyword.repeat
+        }
+    #   ^ punctuation.bracket
+        else {
+    #   ^ keyword.conditional
+    #        ^ punctuation.bracket
+            break
+    #       ^ keyword.repeat
+        }
+    #   ^ punctuation.bracket
+    }
+    # <- punctuation.bracket
+}
+# <- punctuation.bracket
+
+name(42)
+# <- function.call
+#   ^ punctuation.bracket
+#    ^ number
+#      ^ punctuation.bracket
+
+name.name()
+# <- variable
+#   ^ punctuation.delimiter
+#    ^ function.method.call
+#        ^ punctuation.bracket
+#         ^ punctuation.bracket